home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d19 / prodor31.arc / PRO-P.BAT < prev    next >
DOS Batch File  |  1989-10-08  |  3KB  |  152 lines
  1. @echo off
  2. echo off
  3. rem -- pro-p.bat - process "repack" archive request - for ProDOOR 3.1
  4. rem -- %1-resultfile, %2 sourcefile, %3 destfile, %4 playpen
  5.  
  6. rem verify proper command line
  7. if .%4 == . goto usage
  8. if .%5 == . goto pars_ok
  9.  
  10. :usage
  11. echo ERROR! PRO-P.BAT CALLED WITH IMPROPER COMMAND-LINE.
  12. echo P0=%0 P1=%1 P2=%2 P3=%3 P4=%4 P5=%5 >>%1
  13. goto end
  14.  
  15. :pars_ok
  16. rem verify that destination format is known
  17. chkpath testfile %0 >>%1
  18. if errorlevel 1 goto end
  19. testfile %3 arc zip pak lzh zoo
  20. if errorlevel == 98 goto dest_error
  21. if errorlevel == 5 goto destok
  22. if errorlevel == 4 goto destok
  23. if errorlevel == 3 goto destok
  24. if errorlevel == 2 goto destok
  25. if errorlevel == 1 goto destok
  26. goto dest_error
  27.  
  28. :destok
  29. rem verify that the playpen is empty; clean it out if needed
  30. if not exist %4\*.* goto emptyplay
  31. echo Y|del %4 >nul
  32.  
  33. :emptyplay
  34. rem unpack file according to source format
  35. testfile %2 arc zip pak lzh zoo
  36. if errorlevel == 98 goto cant_handle
  37. if errorlevel == 5 goto zoo
  38. if errorlevel == 4 goto lzh
  39. if errorlevel == 3 goto pak
  40. if errorlevel == 2 goto zip
  41. if errorlevel == 1 goto arc
  42. goto cant_handle
  43.  
  44. :zoo
  45. chkpath zoo %0 >>%1
  46. if errorlevel 1 goto unpack_error
  47. zoo -extract >>%1 %2 %4
  48. goto repack
  49.  
  50. :arc
  51. chkpath pkunpak %0 >>%1
  52. if errorlevel 1 goto unpack_error
  53. pkunpak >>%1 %2 %4
  54. goto repack
  55.  
  56. :zip
  57. chkpath pkunzip %0 >>%1
  58. if errorlevel 1 goto unpack_error
  59. pkunzip >>%1 %2 %4
  60. goto repack
  61.  
  62. :pak
  63. chkpath pak %0 >>%1
  64. if errorlevel 1 goto unpack_error
  65. pak e >>%1 %2 %4
  66. goto repack
  67.  
  68. :lzh
  69. chkpath lharc %0 >>%1
  70. if errorlevel 1 goto unpack_error
  71. lharc e /v >>%1 %2 %4\
  72. goto repack
  73.  
  74. :repack
  75. if errorlevel 1 goto unpack_error
  76.  
  77. rem file is unpacked, now repack in destination format
  78. testfile %3 arc zip pak lzh zoo
  79. if errorlevel == 98 goto dest_error
  80. if errorlevel == 5 goto tozoo
  81. if errorlevel == 4 goto tolzh
  82. if errorlevel == 3 goto topak
  83. if errorlevel == 2 goto tozip
  84. if errorlevel == 1 goto toarc
  85. goto cant_handle
  86.  
  87. :tozoo
  88. chkpath zoo %0 >>%1
  89. if errorlevel 1 goto pack_error
  90. zoo -move >>%1 %3 %4\*
  91. goto done
  92.  
  93. :toarc
  94. chkpath pkpakjr %0 >>%1
  95. if errorlevel 1 goto pack_error
  96. pkpakjr -m >>%1 %3 %4\*.*
  97. goto done
  98.  
  99. :tozip
  100. chkpath pkzip %0 >>%1
  101. if errorlevel 1 goto pack_error
  102. pkzip -m -es >>%1 %3 %4\*.*
  103. goto done
  104.  
  105. :topak
  106. chkpath pak %0 >>%1
  107. if errorlevel 1 goto pack_error
  108. pak m >>%1 %3 %4\*.*
  109. goto done
  110.  
  111. :tolzh
  112. chkpath lharc %0 >>%1
  113. if errorlevel 1 goto pack_error
  114. lharc m /v >>%1 %3 %4\*.*
  115. goto done
  116.  
  117. :done
  118. if errorlevel 1 goto pack_error
  119. echo. >>%1
  120. echo %3 created.  Download it before leaving ProDoor. >>%1
  121.  
  122. rem -- remove source file if it has the same name as destination
  123. rem -- (usually happens when repacking ZIPM packets)
  124. chkpath -N %2 %3
  125. if errorlevel 1 goto end
  126. del %2
  127. goto end
  128.  
  129. :dest_error
  130. echo Sorry, %0 does not know how to create %3 ! >>%1
  131. goto end
  132.  
  133. :cant_handle
  134. echo Sorry, %0 does not know how to process %2 ! >>%1
  135. goto end
  136.  
  137. :pack_error
  138. echo Y|del %4 >nul
  139. echo. >>%1
  140. echo %0: Error creating %3. >>%1
  141. echo The system is either low on disk space or memory. >>%1
  142. goto end
  143.  
  144. :unpack_error
  145. echo Y|del %4 >nul
  146. echo. >>%1
  147. echo %0: Error unpacking %2. >>%1
  148. echo The system is either low on disk space or memory. >>%1
  149. goto end
  150.  
  151. :end
  152.